🧑🏾 👾 🏴 Gnuplot 5.0। DIY 4-अक्ष स्पाइडरप्लॉट 🥋 👍🏾 🔩

एक लेख के लिए डेटा विज़ुअलाइज़ेशन पर काम करते समय, सभी पर सकारात्मक लेबल के साथ 4 कुल्हाड़ियों का होना आवश्यक हो गया।

अन्य लेख चार्ट के साथ, मैंने gnuplot का उपयोग करने का निर्णय लिया । सबसे पहले, मैंने आधिकारिक वेबसाइट पर देखा, जहां कई उदाहरण हैं। मुझे बहुत खुशी हुई जब मुझे आवश्यक उदाहरण मिला (मैं एक फ़ाइल के साथ बहुत काम नहीं करूंगा और यह सुंदर होगा, मैंने सोचा)।

जल्दी से कोड की प्रतिलिपि बनाएँ, इसे चलाएँ। मुझे एक त्रुटि मिलती है। मै समझता हुँ। यह पता चला कि मेरे पास एक पुराना gnuplot ( Version 5.0 patchlevel 3 last modified 2016-02-21) है और यह नहीं जानता कि कैसे।

Gnuplot के लचीलेपन को जानने का, वह वर्ल्ड वाइड वेब के आसपास चप्पा चप्पा छान मारना शुरू किया और stackoverflow पर कई उपयुक्त उदाहरण भर में आया था ( डबल x अक्ष gnuplot के साथ एक मकड़ी भूखंड पर और कैसे gnuplot? में एक मकड़ी प्लॉट बनाने के लिए ) और GitHub ( gnuplot-radarchart )। वे शुरुआती बिंदु बन गए।

इसके अलावा, कमांड के साथ मेरे जोड़तोड़ के कारण निम्नलिखित थे:

0) सीमाओं को बंद करें

unset border

1) 4 शून्य लाइनें बनाएं - 2 मुख्य और 2 अतिरिक्त:

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

दस्तावेज़ में शून्य रेखाओं के बारे में कुछ शब्द । यह ऑपरेशन आपको चित्र के केंद्र के अक्ष को कम करने की अनुमति देता है। और उन पर सकारात्मक टिक प्रदर्शित करने के लिए अतिरिक्त लोगों की आवश्यकता होती है।

2) कुल्हाड़ियों पर टिक के प्रदर्शन को कॉन्फ़िगर करें:

max = 1.5 #  
min = -max
set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify

सेटिंग्स के कुल्हाड़ियों पर टिक के साथ थोड़ा और अधिक।
axis- जहां टिक्स स्थित होंगे, अक्ष पर या (सीमा पर - सीमा पर)।
एक अक्ष के xलिए जो दाईं ओर जाता है 0,.5,max। पहली संख्या मूल है, दूसरा चरण है, तीसरा गणना का अंत है। पहले से 0, और बाकी हिस्सों के लिए 0.5, ताकि शून्य मूल में हस्तक्षेप न करें।


निर्देशांक के केंद्र में शून्य मिलाकर। सभी अंतराल के `*tics`रूप में कॉन्फ़िगर किए गए हैं`0,.5,max`	बिना `offset 0.35`के लिए`xtics`

सेटिंग scale 0.5,0.25 mirror अक्ष पर सेरिफ़ जोड़ता है। यदि आप संख्याओं के साथ खेलते हैं, तो उनका आकार बदल जाएगा।
मैं उन चर का भी परिचय max, minदेता हूं जिनके साथ मैं ग्राफ अक्षों की सीमाओं को नियंत्रित करता हूं।
टिक्स सेट करने के बारे में अधिक जानकारी के लिए, Xtics अनुभाग में प्रलेखन देखें ।

3) कॉन्फ़िगर कुल्हाड़ियों पर्वतमाला:

set xrange  [ min : max ] 
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

यह ध्यान दिया जाना चाहिए कि 2 कुल्हाड़ियों की गिनती minबढ़ने से शुरू होती है और 2 कुल्हाड़ियों के maxघटने से शुरू होती है।
अधिक जानकारी के लिए Xrange सेक्शन देखें ।

4) हम कुल्हाड़ियों को नाम देते हैं और उन्हें अच्छी तरह से जगह देते हैं:

set label "H_1" at  0,       max center offset char  2, 0
set label "H_2" at  max+0.1, 0   center offset char -1, 1
set label "H_3" at  0,       min center offset char -2, 0
set label "H_4" at  min,     0   center offset char  0, 1

5) हम इनपुट डेटा बनाते हैं
। प्रत्येक कॉलम में 2 कॉलम हैं। पंक्ति संख्या - अक्ष संख्या, लूप को बंद करने के लिए पांचवीं पंक्ति। विषम स्तंभ - समन्वय x, यहां तक कि - y। इस तथ्य के कारण कि सभी बिंदु कुल्हाड़ियों पर स्थित हैं, एक जोड़ी (x, y)हमेशा शून्य के बराबर होती है।
इस तथ्य के बावजूद कि सभी 4 कुल्हाड़ी सकारात्मक हैं, कुछ डेटा कृत्रिम रूप से नकारात्मक आधा में स्थानांतरित हो जाते हैं, क्योंकि वे मुख्य अक्षों पर स्थित हैं xऔर y।

 0  1  0     1.21
 1  0  1.21  0   
 0 -1  0    -1.06
-1  0 -1.19  0   
 0  1  0     1.21 #

परिणाम
संपूर्ण

पूर्ण कोड

#!/usr/bin/gnuplot -persist
#   cp1251      eps

set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"

unset border
set key at -2, 1.5 font 'LiberationSerif, 23' 
set key left top samplen 4.5

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

max = 1.5
min = -max

set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35 font 'LiberationSerif, 20
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20

set xrange  [ min : max ]
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

set label "H_1" at  0,       max center offset char  2, 0   font 'LiberationSerif, 23'
set label "H_2" at  max+0.1, 0   center offset char -1, 1   font 'LiberationSerif, 23'
set label "H_3" at  0,       min center offset char -2, 0   font 'LiberationSerif, 23'
set label "H_4" at  min,     0   center offset char  0, 1   font 'LiberationSerif, 23'

set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black

plot 'data.csv' using  1:2 title "1" w lp ls 1 ,\
     'data.csv' using  3:4 title "2" w lp ls 2

Gnuplot 5.0। DIY 4-अक्ष स्पाइडरप्लॉट

More articles: