الشروط الأولية
هناك جهاز يعتمد على متحكم (على سبيل المثال ، سيتم أخذ stm32f405rgt6). عند تشغيله ، يقوم بضبط ملحقاته بناءً على تفضيلات المستخدم أو الإعدادات الافتراضية. يمكن للمستخدم تغيير الإعدادات أثناء تشغيل الجهاز (كقاعدة عامة ، فقط أثناء الاندماج في المجمع) من خلال إحدى الواجهات المحتملة (قائمة CLI أو الأداة المساعدة لتعيين معلمات العمل التي تعمل عبر البروتوكول الثنائي). بعد ضبط المعلمات ، يحفظ المستخدم الإعدادات بأمر خاص (أيضًا من خلال إحدى الواجهات المحتملة).مهمة
- لتقليل الوقت المستغرق للوصول إلى متغيرات إعدادات الجهاز أثناء التشغيل ، تحتاج إلى الاحتفاظ بالقيم الحالية في ذاكرة الوصول العشوائي (عادةً ما تختلف كمية هذه البيانات من اثني عشر متغيرات إلى 3 كيلوبايت اعتمادًا على الجهاز).
- من الضروري تخزين إعدادات المستخدم بشكل مكرر في ومضة وحدة التحكم الدقيقة.
- يجب أن ينتهي كل مثيل لإعدادات المستخدم بـ CRC32 مباشرة بعد الحمولة.
- لكل مثيل من إعدادات المستخدم ، يتم استخدام صفحة منفصلة في ذاكرة فلاش (حتى لو كانت البيانات المفيدة 2 كيلو بايت ، والصفحات مقسمة على 128 كيلو بايت ، ثم يتم إعطاء الصفحة بأكملها تحت كتلة واحدة)
- يجب أن يخزن رمز برنامج وحدة التحكم الدقيقة الإعدادات الافتراضية ، والتي يجب أن تكون كتل إعدادات المستخدم إذا كان لكل منهما بيانات تالفة
محاولات لحلها
ليس لدى دول مجلس التعاون الخليجي (في وقت كتابة هذا التقرير) علامة للحصول على نسخة من القسم. فشل أيضًا في إكمال النص البرمجي LD باستخدام "الخطوط السحرية". يمكن للمرء أن يعمل مع إعاقة ، ولكن هذا النهج ضمني للغاية ويؤدي إلى أخطاء دقيقة.القرار
الحل هو إنشاء نسخ ضمنية من الكيان المطلوب (متغير ، بنية ، صفيف ، إلخ) في رمز المستخدم ، متبوعًا بموقعها في الذاكرة.إنشاء ماكرو للنسخ المخفي للبنيات
لنقم بإنشاء ماكرو سنحجز به مكانًا للهيكل في ذاكرة الوصول العشوائي ، ومثالين من ذاكرة فلاش على صفحات منفصلة وفي رمز المستخدم (للقيم الأولية).#define USER_CFG_DATA_STRUCT(TYPE,NAME,...) \
__attribute__((aligned(4), section (".user_cfg_data_ram_page"))) \
TYPE NAME = __VA_ARGS__; \
__attribute__((aligned(4), section (".user_cfg_data_flash_default_page"))) \
TYPE flash_default_page_##NAME = __VA_ARGS__; \
__attribute__((aligned(4), section (".user_cfg_data_flash_page_1"))) \
TYPE flash_page_1_##NAME = __VA_ARGS__; \
__attribute__((aligned(4), section (".user_cfg_data_flash_page_2"))) \
TYPE flash_page_2_##NAME = __VA_ARGS__;
باستخدام الماكرو ، سيتم إنشاء 4 مثيلات للهيكل بأسماء مختلفة. في رمز المشروع (باستثناء النظام للعمل مع صفحات ذاكرة إعدادات المستخدم) ، يجب أن تستخدم جميع الوحدات هيكلًا بدون بادئة (الاسم المحدد في الماكرو) سيكون في ذاكرة الوصول العشوائي (سيكون من الممكن تغيير الوحدات المسؤولة عن تفاعل المستخدم. يجب أن يكون الباقي فقط اقرأ منه).مثال على استخدام ماكرو في كود المستخدم:typedef struct _test_st {
uint32_t a1;
uint32_t a2;
} test_st_t;
USER_CFG_DATA_STRUCT(test_st_t, name_st, {
.a1 = 1,
.a2 = 2
})
بعد أن يتوفر مثيل بنية name_st من رمز المشروع.إنشاء وحدات ماكرو للنسخ المخفي للكيانات الأخرى
لإنشاء متغير ، ما عليك سوى إجراء استبدال الماكرو لإنشاء بنى.بالنسبة للمصفوفات ، أضف عدد العناصر.#define USER_CFG_DATA_VAR USER_CFG_DATA_STRCUT
#define USER_CFG_DATA_ARRAY(TYPE,NAME,SIZE,...) \
__attribute__((aligned(4), section (".user_cfg_data_ram_page"))) \
TYPE NAME[SIZE] = __VA_ARGS__; \
__attribute__((aligned(4), section (".user_cfg_data_flash_default_page"))) \
TYPE flash_default_page_##NAME[SIZE] = __VA_ARGS__; \
__attribute__((aligned(4), section (".user_cfg_data_flash_page_1"))) \
TYPE flash_page_1_##NAME[SIZE] = __VA_ARGS__; \
__attribute__((aligned(4), section (".user_cfg_data_flash_page_2"))) \
TYPE flash_page_2_##NAME[SIZE] = __VA_ARGS__;
مبدأ الاستخدام مشابه لاستخدام الهيكل.وضع اللمسات الأخيرة على البرنامج النصي LD
عند إنشاء نسخ من الكيانات ، تمت الإشارة إلى الأقسام التي تقع فيها. الآن يجب عليك إنشاء هذه الأقسام في البرنامج النصي LD. بالنسبة إلى F4 ، سيبدو نص LD الإضافي المعزز من ST كما يلي:النصي LDMEMORY
{
FLASH (rx) : ORIGIN = 0x08000000, LENGTH = 1024K - 256K
USER_CFG_PAGE_1 (rx) : ORIGIN = 0x080C0000, LENGTH = 128K - 4
USER_CFG_PAGE_2 (rx) : ORIGIN = 0x080E0000, LENGTH = 128K - 4
CCM (xrw) : ORIGIN = 0x10000000, LENGTH = 64K
RAM (xrw) : ORIGIN = 0x20000000, LENGTH = 128K
}
user_cfg_data_flash_page_1_size = LENGTH(user_cfg_PAGE_1) + 4;
user_cfg_data_flash_page_2_size = LENGTH(user_cfg_PAGE_2) + 4;
user_cfg_data_flash_page_size = user_cfg_data_flash_page_1_size;
__stack = ORIGIN(RAM) + LENGTH(RAM);
_estack = __stack;
__Main_Stack_Size = 1024 ;
PROVIDE ( _Main_Stack_Size = __Main_Stack_Size ) ;
__Main_Stack_Limit = __stack - __Main_Stack_Size ;
PROVIDE ( _Main_Stack_Limit = __Main_Stack_Limit ) ;
_Minimum_Stack_Size = 512 ;
PROVIDE ( _Heap_Begin = _end_noinit ) ;
PROVIDE ( _Heap_Limit = __stack - __Main_Stack_Size ) ;
SECTIONS
{
.isr_vector :
{
KEEP(*(.isr_vector))
KEEP(*(.cfmconfig))
*(.after_vectors .after_vectors.*)
. = ALIGN(4);
} >FLASH
.inits :
{
. = ALIGN(4);
KEEP(*(.init))
KEEP(*(.fini))
. = ALIGN(4);
PROVIDE_HIDDEN (__preinit_array_start = .);
KEEP(*(.preinit_array_sysinit .preinit_array_sysinit.*))
KEEP(*(.preinit_array_platform .preinit_array_platform.*))
KEEP(*(.preinit_array .preinit_array.*))
PROVIDE_HIDDEN (__preinit_array_end = .);
. = ALIGN(4);
PROVIDE_HIDDEN (__init_array_start = .);
KEEP(*(SORT(.init_array.*)))
KEEP(*(.init_array))
PROVIDE_HIDDEN (__init_array_end = .);
. = ALIGN(4);
PROVIDE_HIDDEN (__fini_array_start = .);
KEEP(*(SORT(.fini_array.*)))
KEEP(*(.fini_array))
PROVIDE_HIDDEN (__fini_array_end = .);
. = ALIGN(4);
} >FLASH
.flashtext :
{
. = ALIGN(4);
*(.flashtext .flashtext.*)
. = ALIGN(4);
} >FLASH
.text :
{
. = ALIGN(4);
*(.text .text.*)
*(.rodata .rodata.*)
*(vtable)
KEEP(*(.eh_frame*))
*(.glue_7)
*(.glue_7t)
} >FLASH
.user_cfg_data_flash_default_page :
{
. = ALIGN(4);
user_cfg_data_flash_default_page_start = .;
KEEP(*(.user_cfg_data_flash_default_page .user_cfg_data_flash_default_page.*))
. = ALIGN(4);
user_cfg_data_flash_default_page_stop = .;
} >FLASH
.ARM.extab :
{
*(.ARM.extab* .gnu.linkonce.armextab.*)
} > FLASH
__exidx_start = .;
.ARM.exidx :
{
*(.ARM.exidx* .gnu.linkonce.armexidx.*)
} > FLASH
__exidx_end = .;
. = ALIGN(4);
_etext = .;
__etext = .;
_sidata = _etext;
.data : AT ( _sidata )
{
. = ALIGN(4);
_sdata = . ;
__data_start__ = . ;
*(.data_begin .data_begin.*)
*(.data .data.*)
*(.data_end .data_end.*)
*(.ramfunc*)
. = ALIGN(4);
_edata = . ;
__data_end__ = . ;
} >RAM
.bss (NOLOAD) :
{
. = ALIGN(4);
__bss_start__ = .;
_sbss = .;
*(.bss_begin .bss_begin.*)
*(.bss .bss.*)
*(COMMON)
*(.bss_end .bss_end.*)
. = ALIGN(4);
__bss_end__ = .;
_ebss = . ;
} >RAM
.user_cfg_data_ram_page :
{
. = ALIGN(4);
user_cfg_data_ram_page_start = .;
KEEP(*(.user_cfg_data_ram_page .user_cfg_data_ram_page.*))
. = ALIGN(4);
user_cfg_data_ram_page_stop = .;
} > CCM
user_cfg_data_ram_page_size = user_cfg_data_ram_page_stop - user_cfg_data_ram_page_start;
.user_cfg_data_page_1 :
{
. = ALIGN(4);
user_cfg_data_flash_page_1_start = .;
KEEP(*(.user_cfg_data_flash_page_1 .user_cfg_data_flash_page_1.*))
. = ALIGN(4);
user_cfg_data_flash_page_1_stop = .;
} > user_cfg_PAGE_1
.user_cfg_data_page_2 :
{
. = ALIGN(4);
user_cfg_data_flash_page_2_start = .;
KEEP(*(.user_cfg_data_flash_page_2 .user_cfg_data_flash_page_2.*))
. = ALIGN(4);
user_cfg_data_flash_page_2_stop = .;
} > user_cfg_PAGE_2
.noinit (NOLOAD) :
{
. = ALIGN(4);
_noinit = .;
*(.noinit .noinit.*)
. = ALIGN(4) ;
_end_noinit = .;
} > RAM
PROVIDE ( end = _end_noinit );
PROVIDE ( _end = _end_noinit );
PROVIDE ( __end = _end_noinit );
PROVIDE ( __end__ = _end_noinit );
._check_stack :
{
. = ALIGN(4);
. = . + _Minimum_Stack_Size ;
. = ALIGN(4);
} >RAM
.stab 0 : { *(.stab) }
.stabstr 0 : { *(.stabstr) }
.stab.excl 0 : { *(.stab.excl) }
.stab.exclstr 0 : { *(.stab.exclstr) }
.stab.index 0 : { *(.stab.index) }
.stab.indexstr 0 : { *(.stab.indexstr) }
.comment 0 : { *(.comment) }
.debug 0 : { *(.debug) }
.line 0 : { *(.line) }
.debug_srcinfo 0 : { *(.debug_srcinfo) }
.debug_sfnames 0 : { *(.debug_sfnames) }
.debug_aranges 0 : { *(.debug_aranges) }
.debug_pubnames 0 : { *(.debug_pubnames) }
.debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
.debug_abbrev 0 : { *(.debug_abbrev) }
.debug_line 0 : { *(.debug_line) }
.debug_frame 0 : { *(.debug_frame) }
.debug_str 0 : { *(.debug_str) }
.debug_loc 0 : { *(.debug_loc) }
.debug_macinfo 0 : { *(.debug_macinfo) }
.debug_weaknames 0 : { *(.debug_weaknames) }
.debug_funcnames 0 : { *(.debug_funcnames) }
.debug_typenames 0 : { *(.debug_typenames) }
.debug_varnames 0 : { *(.debug_varnames) }
}
في هذا المثال ، لا تكمن بنية التكوين في منطقة ذاكرة الوصول العشوائي ، ولكن في CCMRAM ، لتحسين الأداء. وألاحظ أيضًا أن كتل بيانات إعدادات المستخدم هي آخر صفحتين فلاش ، كل منهما 128 كيلو بايت.التهيئة والتحكم في النسخ
رعاية ما سيقع في ذاكرة الوصول العشوائي تقع على عاتق المبرمج. قبل استخدام البيانات من هذه المنطقة للمرة الأولى ، تحتاج إلى تهيئة المنطقة. في الفلاش ، عند تحميل البرنامج في وحدة التحكم الدقيقة ، سيتم تسجيل البيانات مسبقًا بالقيم الأولية المحددة في رمز البرنامج. سيؤدي ذلك إلى إنشاء نسخ غير صالحة من كتل إعدادات المستخدم في صفحات منفصلة إذا كانت تنتهي بـ CRC32 (نظرًا لأنه لم يتم إجراء حساب CRC32. يمكن لكودك القيام بذلك. حتى الاستخدام الأول لمعلمات التكوين).لكتابة وحدة للعمل مع كتل التكوين ، ستحتاج إلى استخدام المتغيرات من البرنامج النصي LD. ما يلي مطلوب:extern uint32_t user_cfg_data_flash_default_page_start;
extern uint32_t user_cfg_data_flash_page_1_start;
extern uint32_t user_cfg_data_flash_page_2_start;
extern uint32_t user_cfg_data_ram_page_start;
extern uint32_t user_cfg_data_flash_page_size;
extern uint32_t user_cfg_data_ram_page_size;
ولا تنس أيضًا أنه يمكن تعيين user_cfg_data_flash_page_size و user_cfg_data_ram_page_size كقيم عادية. ولكن يجب تحديد user_cfg_data_flash_page_1_start والمتغيرات الأخرى التي تخزن العنوان عبر &.